對于一般交易者，ＣＤＰ這一指標是有著很大用處，它可用于一種極短線的操作，即當日內同時買進賣出。我們先來談談其一般的用法：
計算方法
１．先計算ＣＤＰ值（需求值）
ＣＤＰ＝（Ｈ＋Ｌ＋２Ｃ）÷４
Ｈ：前一日最高價，Ｌ：前一日最低價，Ｃ：前一日收市價
２．計算
ＡＨ（最高值）＝ＣＤＰ＋（Ｈ－Ｌ）ＮＨ（近高值）＝ＣＤＰ×２－ＬＡＬ（最低值）＝ＣＤＰ－（Ｈ－Ｌ）ＮＬ（近低值）＝ＣＤＰ×２－Ｈ則此五個數值的排列順序為（從最高到最低）：ＡＨ，ＮＨ，ＣＤＰ，ＮＬ，ＡＬ。
運用原則
找出這五個數值之后，即用前一天的行情波動將當日的未來行情做一個高低等級的劃分。分析者可利用這個高低區分來判斷當日走勢。
研判的關鍵是開市價在ＣＤＰ五個數值的哪個位置，因開市價通常由市場買賣雙方心理期望合理價的折衷后形成的，影響當天的走勢。
1.當開盤價高于CDP時，屬于強市；當開盤價低于CDP時，屬于弱市。
2.在波動并不很大的情況下，即開市價處在近高值與近低值之間，通常交易者可以在近低值的價位買進，而在近高期的價位賣出；或在近高值的價位賣出，近低值的價位買進。
3.在波動較大的情況下，即開市價開在最高值或最低值附近時，意味著跳空開高或跳空開低，是一個大行情的發動開始。因此，交易者可在最高值的價位去追買，最低值的價位去追賣。通常一個跳空，意味著一個強烈的漲跌，應有相當的利潤。（對于大幅高開或低開，已經偏離最高值和最低值有一定距離，則不能按上述操作，如201001111的大盤）
4.手中持股，股價漲到NH減倉，繼續漲到AH繼續減倉，有時弱勢的時候漲到CDP就可以減倉，直接跳空開在AL附近或者逐步跌破AL不收回則斬倉出局；手中無股，股價跌到NL加倉，繼續跌到AL繼續加倉，有時強勢的時候跌到CDP就可以加倉，直接跳空開在AH附近或者逐步拉高站穩AH則可追入（注意由于股票T+1,買入后跌破AL也只能在次日操作，而賣出后突破AH則可追回）
功能分析
１．ＣＤＰ最適合于上下震蕩的盤局行情，選擇高賣低買的區間賺取短線利潤。
２．對于大漲大跌的行情，尤其是沖破阻力價和支撐位時，為避免軋空或橫壓，需設停損點，防止突發性利多或利空的影響。
（對于中長線看好的票，可以拿一部分倉位做短差降成本，當然用cdp測算出來的數值只是一個買賣點的參考，還可以根據壓單托單，分時走勢做短差降成本）
CDP：
PT:=REF(H,1)-REF(L,1);
CDP: (REF(H,1)+REF(L,1)+REF(C,1)*2)/4;
AH: (CDP+PT);
NH: (2*CDP-REF(L,1));
NL: (2*CDP-REF(H,1));
AL: (CDP-PT);
功能描述：該指標在今日收盤的時候無法看到次日的數值，只有在次日開盤時能看到當日的數值
CDP: (REF(H,1)+REF(L,1)+REF(C,1)*2)/4; 說明昨日收盤價是三個價格中最重要的，占的權重大
CDP: (REF(H,1)+REF(L,1)+REF(C,1))/3; 說明昨日的三個價格同樣重要
CDP1:
PT:=REF(H,1)-REF(L,1);
CDP: (REF(H,1)+REF(L,1)+REF(C,1))/3;
AH: (CDP+PT);
NH: (2*CDP-REF(L,1));
NL: (2*CDP-REF(H,1));
AL: (CDP-PT);
通常可以把CDP和CDP1相應等級組成的價格區間（以及該區間100%+/-0.5%）作為盤中的買賣區間
源碼二：
CDP2：
PT := HIGH - LOW;
CDP : (HIGH + LOW +2 * CLOSE)/4;
AH : CDP + PT;
NH : 2*CDP-LOW;
NL : 2*CDP-HIGH;
AL : CDP - PT;
功能描述：該指標只適用在今日收盤后提前測算出明日的值，且今日的收盤價是最重要，當日盤中不適用，需要看前一日的數值
CDP3:
PT := HIGH - LOW;
CDP : (HIGH + LOW + CLOSE)/3;
AH : CDP + PT;
NH : 2*CDP-LOW;
NL : 2*CDP-HIGH;
AL : CDP - PT;
功能描述：該指標只適用在今日收盤后提前測算出明日的值，且三個價格同等重要，當日盤中不適用，需要看前一日的數值
通常可以把CDP2和CDP3相應等級組成的價格區間（以及該區間100%+/-0.5%）作為買賣區間
源碼三：
CDP加強版：
PT:=REF(H,1)-REF(L,1);
CDP:=(REF(H,1)+REF(L,1)+REF(C,1)*2)/4;
AH:=CDP+PT;
AL:=CDP-PT;
NH:=CDP*2-REF(L,1);
NL:=CDP*2-REF(H,1);
強:IF(AH>REF(C,1)*1.1,REF(C,1)*1.1,AH)NODRAW;
阻:IF(NH>強,(強-CDP)*0.618+CDP,NH)NODRAW,COLORCYAN;
M:=IF(AL<REF(C,1)/1.1,REF(C,1)/1.1,AL);
撐:IF(NL<M,CDP-(CDP-M)*0.618,NL)NODRAW;
底:IF(AL<REF(C,1)/1.1,REF(C,1)/1.1,AL)NODRAW;
功能描述：考慮到了股票的漲跌停限制，當振幅不大時，數值和CDP是完全一樣的；只有當振幅較大時，比如權證或者連續拉漲跌停后大幅震蕩，數值和CDP不完全相同或者完全不相同，此時結合兩個指標，相當于多了幾個等級，多了一個（或兩個）支撐位和阻力位，以CDP指標為主，CDP加強指標為輔
（南方財富網SOUTHMONEY.COM）（責任編輯：張曉軒）